基本的 51 单片机有四个并行口，其中还包含了一个串行口。

当接口不够用的时候，大家就会想到，使用什么外接芯片来扩充。

但是，各种教材、参考书、网络文章，介绍扩充并行口的花样不少，扩充串行口的方法，几乎无人问津。

偶尔见到一个，也是使用 8250、8251 等“巨型”芯片来扩充的

使用这些芯片，就要占用单片机很多的更为紧缺的并行口，基本上就是得不偿失。更别说还要设置复杂的控制字了。

做而论道使用简单的三态门，即可为单片机扩充串行口，仅仅占用单片机的一、二个引脚作为控制引线而已。

这个方法，在以前的各种书籍、杂志、网文中，都没有见到过，可以说是做而论道的独创。

呵呵，小小的自豪一下，请不要拍砖。

实际上是很简单的，就像使用 74LS373、74LS244 扩充并行口一样，为串行口，配上合适三态门就行了。

选用 74LS125(低电平开门)、74LS126(高电平开门) 都行。

使用其它的具有三态输出的芯片也可以，如：74LS244、74LS373 等等。

只是这些芯片的控制线，是成组的控制，不是单独的一个门、一个门的进行控制，就有些不够方便。

下面就是做而论道设计的扩充两个串口通道的电路图：

为了控制简单，以及介绍全面一些，在图中使用了两种三态门。用同一种，也是可以的。

两组三态门，均以 P3.4 作为控制信号。

当 P3.4 输出高电平时，74LS126 开门，通道1导通，单片机即可对 74LS164 进行串行输出，驱动数码管；

当 P3.4 输出低电平时，74LS125 开门，通道2导通，单片机即可与其它串口设备进行全双工的通信。

如果需要，还可以在 125 的右边再接上 TTL-RS232 电平转换芯片(或 RS485 总线芯片)，进行远距离通信。

图中是接上了一个 PROTEUS 软件的虚拟终端，用来代表另一个串口通信设备。

做而论道用汇编语言写了一小段程序，可以控制这个串口扩展电路进行工作。

;=================================================

ORG 0000H

SJMP START

ORG 0023H

AJMP S_INT

START:

MOV TMOD, #20H

MOV TH1, #0FDH ;设置波特率9600@11.0592MHz

MOV TL1, #0FDH

SETB TR1

MOV IE, #90H ;开串口中断

CLR P3.4 ;选通74LS125(通道2)

MOV SCON, #50H ;串口方式1, 可接收

SJMP $

;-----------------------------------

S_INT: ;串口中断程序

JNB RI, S_END

CLR RI

MOV A, SBUF ;取出收到的数据

;---------------------

SETB P3.4 ;选通74LS126(通道1)

MOV SCON, #0 ;串口通信方式0

MOV B, #16

DIV AB

XCH A, B

ADD A, #(TAB - $ - 3)

MOVC A, @A + PC ;取七段码

MOV SBUF, A ;串口输出

JNB TI, $ ;等待发送完毕

CLR TI

MOV A, B

ADD A, #(TAB - $ - 3)

MOVC A, @A + PC

MOV SBUF, A

JNB TI, $

CLR TI

;---------------------

CLR P3.4 ;选通74LS125(通道2)

MOV SCON, #50H ;串口方式1, 可接收

MOV SBUF, #'O'

JNB TI, $

CLR TI

MOV SBUF, #'K'

JNB TI, $

CLR TI

MOV SBUF, #13 ;<CR>

JNB TI, $

CLR TI

MOV SBUF, #10 ;<LF>

JNB TI, $

CLR TI

;---------------------

S_END:

RETI

TAB: ;共阳段码表

DB 0C0H, 0F9H, 0A4H, 0B0H, 099H, 092H, 082H, 0F8H;0~7

DB 080H, 090H, 088H, 083H, 0C6H, 0A1H, 086H, 08EH;8~F

END

;=================================================

程序执行后，屏幕截图如下：

在程序控制下，51 单片机随时监听通道2，一旦虚拟终端发来了一个字节的串行数据，单片机都要向虚拟终端回送 'OK'<CR><LF>。

这时，就是单片机和上位机之间的双工串行通信。

然后，单片机转向串口通道1，以方式0 输出两组七段码，令外接的 74LS164 显示刚刚收到的数据的高、低四位。

这时，就是简单的 SPI 通信方式。

在图中可以看到，数码管显示的是 41，这是在虚拟终端窗口中键入'A'时的现象，41 即字符 A 的 ASCII 码。

虚拟终端，它并不显示键入的内容，它仅仅显示单片机发出的信息，在图中可以看到显示出来的 OK、回车、换行

74LS125 和 74LS126 都是 14 引脚的集成芯片，和 8250、16550A 等 40 引脚的专用串口芯片相比，要小巧的多。

每片(125 或 126)都含有四个独立工作的三态门。实际上，使用一片 125 或 126，也就可以实现上述的两个通道串口通信了。

注意：如果使用了一片芯片，那么通道控制的电平信号是相同的，这就需要使用单片机的两个引脚来分别控制两个通道。

多用几片三态门，为单片机多扩充几个串行口，也是可行的。

做而论道设计的这种串口扩充方案，硬件电路和软件，都已经在实际电路中做过实验，可以正常通信。